Namaran

Code daily. Without assist.

2026-10-24

encoded_len.zig

const std = @import("std");

const Value = union(enum) {
    byte: u8,
    word: u32,
    text: []const u8,
};

fn encodedLen(v: Value) usize {
    return switch (v) {
        inline else => |x| @sizeOf(@TypeOf(x)),
    };
}

pub fn main(init: std.process.Init) !void {
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    try stdout.print("{d} {d}\n", .{ encodedLen(.{ .word = 7 }), encodedLen(.{ .text = "hello" }) });
    try stdout.flush();
}

encodedLen は、Value の中身をバイト列に書き出したときの長さを返すつもりの関数です。数値は型の大きさのまま書き出し、text は文字列のバイトだけを書き出します。main は u32 の 7 と文字列 "hello" を渡します。いまの出力は 4 16 です。本来の出力は 4 5 です。

Answer

Wrong

return switch (v) {
    inline else => |x| @sizeOf(@TypeOf(x)),
};

inline else はタグごとに腕(prong)を展開し、.text の腕では x の型が []const u8 になります。スライスは先頭を指すポインタと長さの組なので、@sizeOf([]const u8) は文字列の長さとは関係なく、64ビットの環境ではポインタ8バイトと長さ8バイトの 16 です。.byte と .word の腕では型の大きさがそのまま中身の大きさなので、正しい値が出ます。測り違えているのは .text の腕だけで、文字列ではなくスライスそのものの大きさを返しています。

Right

return switch (v) {
    .text => |s| s.len,
    inline else => |x| @sizeOf(@TypeOf(x)),
};

.text の腕を個別に書きます。inline else が展開するのは、ほかの腕が受け持たなかった残りのタグだけなので、.text は s.len の腕で扱われ、"hello" の 5 を返します。.byte と .word はこれまでどおり @sizeOf で測られます。