Namaran

Code daily. Without assist.

2026-10-28

average.zig

const std = @import("std");

fn average(samples: []const usize) usize {
    var total: usize = 0;
    for (samples) |s| total += s;
    return total / samples.len;
}

pub fn main(init: std.process.Init) !void {
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    var samples: [8]usize = @splat(0);
    var count: usize = 0;
    for ([_]usize{ 30, 40, 50 }) |v| {
        samples[count] = v;
        count += 1;
    }
    try stdout.print("{d}\n", .{average(&samples)});
    try stdout.flush();
}

最大8個まで入る配列 samples に測った値を先頭から詰め、入れた個数を count で数えて、入れた値の平均を出力するつもりのコードです。main は30、40、50の3つを入れます。本来は 40 と出力されるはずが、いまは 15 と出力されます。

Answer

Wrong

    try stdout.print("{d}\n", .{average(&samples)});

&samples は配列全体へのポインタ *[8]usize で、引数の型 []const usize へは、長さが配列の長さの8のスライスとして型強制(type coercion)されます。スライスが持つ長さは配列の大きさで決まり、count とは関係がありません。

average は値を入れていない5つの0も含めた8要素を足し、合計120を samples.len の8で割るので、15を返します。0で埋めてあるので合計は変わらず、割る数だけが増えています。

Right

    try stdout.print("{d}\n", .{average(samples[0..count])});

samples[0..count] は、配列の先頭から count 個だけを指すスライスです。count は実行時に決まる値なので、結果は長さを持つスライス []usize になり、samples.len は3になります。average は120を3で割って40を返します1。

  1. Zig のポインタには、1つの値を指す *T、長さをコンパイル時に持つ配列へのポインタ *[N]T、長さを実行時に持つスライス []T、長さを持たない多要素ポインタ(many-item pointer)[*]T があります。*[N]T から []T と [*]T へは暗黙に型強制されますが、そのとき長さは N になるか、失われるかのどちらかです。