2026-10-30
labels.zig
const std = @import("std");
fn labels(buf: []u8, out: [][]const u8, nums: []const u32) !void {
for (nums, out) |n, *slot| {
slot.* = try std.mem.print(buf, "{d}", .{n});
}
}
pub fn main(init: std.process.Init) !void {
var buf: [32]u8 = undefined;
var out: [3][]const u8 = undefined;
try labels(&buf, &out, &.{ 5, 120, 37 });
var obuf: [256]u8 = undefined;
var stdout_writer = std.Io.File.stdout().writer(init.io, &obuf);
const stdout = &stdout_writer.interface;
try stdout.print("{s} {s} {s}\n", .{ out[0], out[1], out[2] });
try stdout.flush();
}
labels は、nums の各数を10進の文字列にして、out の同じ位置にその文字列を入れるつもりの関数です。文字列の中身は buf に置きます。main は 5、120、37 を渡すので、本来は 5 120 37 と出力されるはずが、いまは 3 370 37 と出力されます。
Answer
Wrong
fn labels(buf: []u8, out: [][]const u8, nums: []const u32) !void {
for (nums, out) |n, *slot| {
slot.* = try std.mem.print(buf, "{d}", .{n});
}
}
370 はどの入力にも無い数ですが、長さ3の文字列です。3つの文字列の長さは1、3、2で、入力の 5、120、37 の桁数と一致しています。長さは正しく、中身だけが違うということは、3つのスライスが同じ場所を指していて、その場所が後から書き換えられたと考えられます。
std.mem.print は、渡したバッファの先頭から書き、書いた部分を先頭からのスライスとして返します。毎回 buf をそのまま渡しているので、3つのスライスはどれも buf[0] から始まります。buf の先頭は 5、120 と書かれ、最後の 37 が前の2文字を上書きして 370 になります。そこを長さ1、3、2で切り出すので、3、370、37 が出力されます。
Right
fn labels(buf: []u8, out: [][]const u8, nums: []const u32) !void {
var used: usize = 0;
for (nums, out) |n, *slot| {
slot.* = try std.mem.print(buf[used..], "{d}", .{n});
used += slot.len;
}
}
used に書き終えたバイト数を持ち、次の文字列は buf[used..] に書きます。3つの文字列は buf の中で 512037 と重ならずに並び、それぞれのスライスは自分の部分だけを指すので、どれも後から書き換えられません。buf が足りなくなれば、std.mem.print は error.NoSpaceLeft を返します。