Namaran

Code daily. Without assist.

2026-10-31

deposit.zig

const std = @import("std");

const Account = struct {
    balance: i64,
    fn deposit(self: *Account, amount: i64) void {
        self.balance += amount;
    }
};

pub fn main(init: std.process.Init) !void {
    const accounts = [_]Account{ .{ .balance = 100 }, .{ .balance = 50 } };
    var acc = accounts[1];
    acc.deposit(30);
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    try stdout.print("{d} {d}\n", .{ accounts[0].balance, accounts[1].balance });
    try stdout.flush();
}

口座1の残高に deposit で30を入金し、2つの口座の残高を出力するつもりのプログラムです。本来は 100 80 と出力されるはずが、いまは 100 50 と出力され、入金がどこにも残りません。

Answer

Wrong

const accounts = [_]Account{ .{ .balance = 100 }, .{ .balance = 50 } };
var acc = accounts[1];
acc.deposit(30);

acc は accounts[1] で初期化した別の変数で、中身は口座1のコピーです。deposit の第1引数は *Account なので、acc.deposit(30) はコンパイラが acc のアドレスを取って Account.deposit(&acc, 30) として呼びます。残高が80になるのはコピーの acc で、accounts[1] は50のままです。

要素をコピーするこの書き方では、2つの宣言はこの組み合わせでしかコンパイルが通りません。accounts はどこからも書き換えられないので、var にすると「書き換えない var」としてエラーになり、const にするしかありません。acc を const にすると &acc が *const Account になり、*Account を受け取る deposit に渡せません。コンパイラが要求する形に合わせていくと、コピーに入金する今のコードになります。

Right

var accounts = [_]Account{ .{ .balance = 100 }, .{ .balance = 50 } };
const acc = &accounts[1];
acc.deposit(30);

acc を配列の要素へのポインタ &accounts[1] にします。acc がすでに *Account なので、acc.deposit(30) はそのポインタをそのまま self に渡し、accounts[1] の残高が80になります。const な配列の要素へのポインタは *const Account で deposit に渡せないので、accounts は var に変えます。acc 自身は別の口座を指し直さないので const のままです。