2026-11-04
double_all.zig
const std = @import("std");
pub fn main(init: std.process.Init) !void {
var buf: [256]u8 = undefined;
var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
const stdout = &stdout_writer.interface;
for ([_][]const u8{ "12", "7", "x" }) |s| {
const n = try std.fmt.parseInt(u32, s, 10);
try stdout.print("{d}\n", .{n * 2});
}
try stdout.flush();
}
文字列で与えた数を順に読み、2倍した値を1行ずつ標準出力へ書くつもりのプログラムです。数として読めない文字列が来たら、そこでエラーを返して止まります。main は "12"、"7"、"x" を読みます。本来は 24 と 14 の2行を表示してから error: InvalidCharacter で終わるはずが、いまは1行も表示されず、エラーだけが報告されます。
Answer
Wrong
const stdout = &stdout_writer.interface;
for ([_][]const u8{ "12", "7", "x" }) |s| {
const n = try std.fmt.parseInt(u32, s, 10);
try stdout.print("{d}\n", .{n * 2});
}
try stdout.flush();
stdout.print は標準出力へ直接は書かず、256バイトの buf に文字をためます。24 と 14 の2行はこの時点ではまだ buf の中にあり、最後の stdout.flush() で初めて標準出力へ送られる予定でした。
3つ目の "x" で std.fmt.parseInt が error.InvalidCharacter を返すと、try はその場で main からエラーを返します。ループの後ろにある flush は実行されず、buf にためた2行は書き出されないまま捨てられます。エラーの報告は標準エラーへ出るので、利用者に見えるのはエラーだけです。
Right
const stdout = &stdout_writer.interface;
errdefer stdout.flush() catch {};
for ([_][]const u8{ "12", "7", "x" }) |s| {
const n = try std.fmt.parseInt(u32, s, 10);
try stdout.print("{d}\n", .{n * 2});
}
try stdout.flush();
errdefer に置いた文は、その関数がエラーを返して抜けるときに実行されます。try がどこで main を抜けても、抜ける直前に stdout.flush() が走り、それまでにためた 24 と 14 が標準出力へ出てからエラーが報告されます。errdefer の中ではエラーを返せないので、flush 自体の失敗は catch {} で捨てています。正常に最後まで進んだときは errdefer は実行されず、ループの後ろの try stdout.flush() が書き出しと、その失敗の報告を受け持ちます。1
- どちらの道でも書き出すだけでよく、flush の失敗を報告しなくてよいなら、
defer stdout.flush() catch {};の1行にまとめて、最後のtry stdout.flush()を消す書き方もあります。