Namaran

Code daily. Without assist.

2026-11-06

sell.zig

const std = @import("std");

const Item = struct {
    stock: u32,
    fn sell(self: *Item) void {
        self.stock -= 1;
    }
};

pub fn main(init: std.process.Init) !void {
    var out: [64]u8 = undefined;
    var w = std.Io.File.stdout().writer(init.io, &out);
    const items = [_]Item{ .{ .stock = 3 }, .{ .stock = 5 } };
    var item = items[1];
    item.sell();
    try w.interface.print("{d}\n", .{items[1].stock});
    try w.interface.flush();
}

在庫が3個と5個の2つの品目のうち、2つ目の品目を1個売ってから、その在庫を表示するつもりのプログラムです。いまは 5 が表示されます。本来は1個減った 4 です。

Answer

Wrong

const items = [_]Item{ .{ .stock = 3 }, .{ .stock = 5 } };
var item = items[1];
item.sell();

Zig の構造体の代入は値のコピーです。var item = items[1]; は items[1] と同じ中身を持つ新しい変数 item を作り、items[1] との結び付きはそこで切れます。item.sell() は Item.sell(&item) と同じ呼び出しで、self にはコピーである item のアドレスが入ります。減るのは item.stock だけで、5から4になったあとは誰にも読まれず、items[1].stock は5のまま表示されます。

items が const なのも、この欠陥の表れです。Zig は書き換えないローカル変数を var で宣言するとコンパイルエラーにするので、このコードでは items を const にしないと通りません。売ったはずの配列を、コンパイラは一度も書き換えられていないものとして扱っています。

Right

var items = [_]Item{ .{ .stock = 3 }, .{ .stock = 5 } };
const item = &items[1];
item.sell();

&items[1] で要素そのものへのポインタを取れば、item は *Item になります。ポインタに対する item.sell() は、そのポインタをそのまま self に渡すので、items[1].stock が4に減ります。items は var に戻します。const の配列の要素へのポインタは *const Item で、*Item を受け取る sell には渡せないからです。item 自身は別の要素を指し直さないので const で宣言します。