Namaran

Code daily. Without assist.

2026-11-07

set_int.zig

const std = @import("std");

const Value = union(enum) { int: i64, text: []const u8 };

fn setInt(v: *Value, n: i64) void {
    v.int = n;
}

pub fn main(init: std.process.Init) !void {
    var out: [64]u8 = undefined;
    var w = std.Io.File.stdout().writer(init.io, &out);
    var v: Value = .{ .text = "none" };
    setInt(&v, 42);
    try w.interface.print("{d}\n", .{v.int});
    try w.interface.flush();
}

文字列か整数のどちらかを持つ Value を、setInt で整数42に置き換えてから表示するつもりのプログラムです。v は文字列 "none" を持った状態から始めます。本来は 42 と表示されます。いまは Debug ビルドで実行すると、setInt の中でパニックして止まり、何も表示されません。

Answer

Wrong

fn setInt(v: *Value, n: i64) void {
    v.int = n;
}

タグ付きunionでは、有効なフィールドは一度に1つだけで、どれが有効かはタグが覚えています。v は .text を有効にして作ったので、タグは text です。v.int = n はフィールド int への代入で、タグを書き換えません。有効でないフィールドへのアクセスは、読み出しでも代入でも illegal behavior で、Debug ビルドでは安全検査が access of union field 'int' while field 'text' is active というパニックで止めます。安全検査を外した ReleaseFast ビルドでは止まらず、何が起きるかは決まっていません。

Right

fn setInt(v: *Value, n: i64) void {
    v.* = .{ .int = n };
}

有効なフィールドを切り替えるには、union全体に新しい値を代入します。v.* = .{ .int = n } はタグを int にし、ペイロードに n を入れた値で v の指す先を丸ごと置き換えるので、main の v.int は有効なフィールドの読み出しになり、42 が表示されます。v.int = n の形は、すでに int が有効なときに値だけを変える場合にだけ使えます。