Namaran

Code daily. Without assist.

2026-11-08

diagonal.zig

const std = @import("std");

pub fn main(init: std.process.Init) !void {
    var out: [64]u8 = undefined;
    var w = std.Io.File.stdout().writer(init.io, &out);
    var row: [3]u8 = @splat('.');
    const grid: [3][]u8 = @splat(&row);
    for (0..3) |i| grid[i][i] = '#';
    for (grid) |r| try w.interface.print("{s}\n", .{r});
    try w.interface.flush();
}

3×3 のマス目を . で埋め、左上から右下への対角線のマスだけを # にして、1行ずつ表示するつもりのプログラムです。本来は #..、.#.、..# の3行が表示されるはずが、いまは ### が3行表示されます。

Answer

Wrong

var row: [3]u8 = @splat('.');
const grid: [3][]u8 = @splat(&row);

@splat(x) は、すべての要素が x の写しである配列を作ります。ここで写される x は &row から変換したスライス []u8 で、スライスの値は先頭を指すポインタと長さの組です。写されるのはこの組だけで、row の3バイトは写されないので、grid の3つの行はどれも同じ row を指します。grid[i][i] = '#' は i が0、1、2のときにそれぞれ row[0]、row[1]、row[2] を書き換えるので、row は ### になり、3つの行はどれもその row を表示します。

grid が const なのに書き込みがコンパイルを通ることも、この共有を示しています。const が固定するのは grid が持つ3つのスライス(ポインタと長さ)で、スライスが指す先の u8 は書き換えられます。書き込んでいるのは grid ではなく row なのです。

Right

var grid: [3][3]u8 = @splat(@splat('.'));

要素の型を配列 [3]u8 にすると、@splat が写すのは3バイトの中身そのものになり、3つの行はそれぞれ別の記憶域を持ちます1。内側の @splat('.') が . を3つ並べた行を作り、外側の @splat がその行を3つ写します。grid[i][i] = '#' は i 行目だけを書き換えるので、#..、.#.、..# が表示されます。今度は grid 自身の中身を書き換えるので、const では書き込みがコンパイルエラーになり、var にする必要があります。

  1. Python の [['.'] * 3] * 3 も、同じ1つのリストへの参照を3つ並べるので、1か所を書き換えると3行すべてが変わります。Zig の配列は値として写されるので、要素を配列にすればこの共有は起きません。