Namaran

Code daily. Without assist.

2026-11-11

stack.zig

const std = @import("std");

fn Stack(comptime n: usize) type {
    return struct {
        items: [n]u8 = undefined,
        len: std.math.IntFittingRange(0, n - 1) = 0,
        fn push(self: *@This(), c: u8) void {
            self.items[self.len] = c;
            self.len += 1;
        }
    };
}

pub fn main(init: std.process.Init) !void {
    var s: Stack(4) = .{};
    for ("abcd") |c| s.push(c);
    try std.Io.File.stdout().writeStreamingAll(init.io, s.items[0..s.len]);
}

Stack(n) は、文字を最大 n 個積める固定長のスタックの型を返す関数です。Stack(4) に abcd を1文字ずつ積んでから中身を表示すると、本来は abcd を出力するはずが、いまは手元の実行で4文字目の push が integer overflow の panic で止まります。同じように Stack(3) に3文字、Stack(5) に5文字を積むと、どちらも満杯まで正しく積めます。

Answer

Wrong

        len: std.math.IntFittingRange(0, n - 1) = 0,

std.math.IntFittingRange(0, k) は、0 から k までを表せるいちばん小さい符号なし整数型を返します。上限を n - 1 にすると、len を items の添字と同じ範囲として扱うことになります。しかし len は積んだ個数で、空の0から満杯の n までの n + 1 通りの値を取ります。Stack(4) では型が 0 から 3 までの u2 になり、4文字目を積んで len を4にする self.len += 1 がオーバーフローします。Debug ビルドはこの illegal behavior を安全検査で止めるので、panic になります。1

3 や 5 で動くのは、0 から n − 1 を表す型と 0 から n を表す型が、たまたま同じだからです。Stack(3) は上限2でも3でも u2、Stack(5) は上限4でも5でも u3 です。上限が n − 1 から n に増えたときに1ビット足りなくなるのは、n が2の累乗で、n − 1 がちょうどそのビット数で表せる最大値のときだけです。

Right

        len: std.math.IntFittingRange(0, n) = 0,

上限を n にすれば、len の型は満杯の個数まで表せます。Stack(4) では u3 になり、4文字目のあとの len は4のまま収まって abcd が表示されます。添字として使うときは 0 から n − 1 の範囲に収まり、items を読み書きする側は変わりません。

  1. panic で止まるのは、安全検査のある Debug と ReleaseSafe だけです。ReleaseFast や ReleaseSmall ではこの足し算が検査されず、その後の動きは保証されません。