Namaran

Code daily. Without assist.

2026-11-13

average.zig

const std = @import("std");

fn average(xs: anytype) usize {
    var sum: @TypeOf(xs[0]) = 0;
    for (xs) |x| sum += x;
    return sum / xs.len;
}

pub fn main(init: std.process.Init) !void {
    const scores = [_]u8{ 200, 100, 60 };
    var buf: [64]u8 = undefined;
    var w = std.Io.File.stdout().writer(init.io, &buf);
    try w.interface.print("{d}\n", .{average(scores)});
    try w.interface.flush();
}

average は、整数の配列を受け取って要素の平均(小数点以下は切り捨て)を返すつもりの関数です。点数 200、100、60 の平均を表示すると、本来は 120 を出力するはずが、いまは何も出力されず、手元の実行では integer overflow の panic で止まります。

Answer

Wrong

    var sum: @TypeOf(xs[0]) = 0;
    for (xs) |x| sum += x;

@TypeOf(xs[0]) は要素の型で、scores を渡したときは u8 です。合計 sum も u8 になり、0 から 255 までしか表せません。200 に 100 を足して300にする2回目の sum += x で範囲を超え、Debug ビルドの安全検査がこの illegal behavior を止めて panic になります。1 要素の1つ1つが u8 に収まっていても、足し合わせた値が収まるとは限りません。

Right

    var sum: usize = 0;
    for (xs) |x| sum += x;

合計を戻り値と同じ usize で持てば、u8 の x は足すときに usize へ広がり、200 + 100 + 60 = 360 をそのまま保てます。360 を要素数の3で割った 120 が返り、表示されます。u8 の要素を usize に足す限り、合計が usize を超えるには配列がメモリに収まらないほど長くなければなりません。

  1. panic で止まるのは、安全検査のある Debug と ReleaseSafe だけです。ReleaseFast や ReleaseSmall ではこの足し算は検査されず、その後の動きは保証されません。