Namaran

Code daily. Without assist.

2026-11-15

read_len.zig

const std = @import("std");

fn readLen(msg: []const u8) u32 {
    const p: *const u32 = @ptrCast(@alignCast(msg[1..5]));
    return std.mem.littleToNative(u32, p.*);
}

pub fn main(init: std.process.Init) !void {
    const msg: [5]u8 align(4) = .{ 7, 42, 0, 0, 0 };
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    try stdout.print("{d}\n", .{readLen(&msg)});
    try stdout.flush();
}

readLen は、先頭の1バイトの種別に続く4バイトを、リトルエンディアンの u32 の長さとして読むつもりの関数です。msg の長さは 42 なので 42 を出力するはずが、いまは何も出力せずに panic: incorrect alignment で止まります。

Answer

Wrong

const p: *const u32 = @ptrCast(@alignCast(msg[1..5]));

*const u32 は、指す先のアドレスが4の倍数であることを型の一部として約束するポインタです。msg[1..5] のポインタの型は *const [4]u8 で、アラインメントは1しか保証されないので、@ptrCast だけではこの約束を作れません。そこで @alignCast を挟んでいますが、@alignCast は約束を実行時に確かめる組み込み関数で、アドレスを揃える働きはありません。

msg は align(4) なので先頭のアドレスは4の倍数で、そこから1バイト進んだ msg[1] のアドレスは4で割ると1余ります。Debug ビルドの安全検査がこれを見つけ、@alignCast の行で panic します。安全検査を外したビルドでは、揃っていないアドレスを揃っていると偽った時点で illegal behavior になり、結果は保証されません。

Right

const p: *align(1) const u32 = @ptrCast(msg[1..5]);

*align(1) const u32 は、アドレスが揃っていなくてもよい u32 へのポインタです。アラインメントを上げないので @alignCast は要らず、@ptrCast だけで変換できます。このポインタから読むと、コンパイラは揃っていないアドレスでも正しく読める命令を使うので、p.* は msg[1] から msg[4] の4バイトを1つの u32 として読み、42 を返します。1

  1. 標準ライブラリの std.mem.readInt(u32, msg[1..5], .little) を使えば、ポインタを変換せずに、エンディアンも指定して同じ値を読めます。