Namaran

Code daily. Without assist.

2026-08-30

copy.zig

const std = @import("std");

fn bump(arr: [3]u8) [3]u8 {
    var out = arr;
    out[0] += 10;
    return out;
}

pub fn main(init: std.process.Init) !void {
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    var a = [3]u8{ 1, 2, 3 };
    const b = bump(a);
    a[1] = 0;
    try stdout.print("{any} {any}\n", .{ a, b });
    try stdout.flush();
}

これは何を出力するでしょうか?

Answer

Output

{ 1, 0, 3 } { 11, 2, 3 }

Zig の配列 [3]u8 は、3つの要素そのものを中に持つ値です。bump(a) は引数 arr として a と同じ中身の配列を受け取り、var out = arr; の代入でも3つの要素がそのまま写されます。out[0] += 10 が書き換えるのは out の要素だけで、arr にも呼び出し側の a にも届きません。return out; で返った配列が b になり、b は { 11, 2, 3 } です。

bump から戻ったあとの a[1] = 0 も、a の要素を変えるだけです。b は a とは別の場所にある配列なので、b[1] は 2 のままで、a は { 1, 0, 3 } になります。配列を引数に渡すと要素への参照が渡ると考えると、a の先頭も 11 に、b の2番目も 0 になると読んでしまいます。{any} は配列を { 1, 0, 3 } の形で書き出します。1

  1. Zig の引数は関数の中で書き換えられないので、bump は arr を直接は変えられず、var out に写してから書き換えています。引数の配列を実際に写すか、写さずに参照で渡すかはコンパイラが選んでよいことになっていますが、引数を書き換えられない以上、どちらを選んでも結果は同じです。