Namaran

Code daily. Without assist.

2026-10-21

tag.zig

const std = @import("std");

fn tag() u8 {
    return if (@inComptime()) 'C' else 'R';
}

fn twice() [2]u8 {
    return .{ tag(), tag() };
}

pub fn main(init: std.process.Init) !void {
    var buf: [256]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    const a = tag();
    const b = comptime twice();
    const c = twice();
    try stdout.print("{c}{s}{s}\n", .{ a, b, c });
    try stdout.flush();
}

これは何を出力するでしょうか?

Answer

RCCRR です。

@inComptime() は、その呼び出しがコンパイル時に評価されているときに true を返します。const a = tag(); の tag は引数を取らず、結果も入力に依らないので、コンパイル時に計算されそうに見えます。しかし Zig は、引数がすべてコンパイル時にわかっているというだけでは関数呼び出しをコンパイル時に評価しません。関数の中の呼び出しがコンパイル時に評価されるのは、comptime を付けた式の中など、コンパイル時の文脈に置かれたときだけです。a を const で宣言してもこれは変わらず、tag は実行時に呼ばれて 'R' を返します。

comptime twice() は、twice の呼び出し全体をコンパイル時に評価させます。twice の本体で呼ぶ2つの tag() も、同じコンパイル時の評価の中で実行されるので、どちらも 'C' を返し、b は "CC" になります。comptime を付けない twice() は実行時に呼ばれ、その中の tag() も実行時なので c は "RR" です。同じ tag の本体でも、文脈が呼び出しの経路をたどって伝わり、外側の呼び出しがどこで評価されたかで結果が決まります1。

  1. コンパイラは、実行時に呼ばれる tag では @inComptime() を false に置き換え、else 側だけを残します。コンパイル時の評価とは別に、実行時用の本体が1つ作られます。