Namaran

Code daily. Without assist.

2026-11-03

Stock.hs

import Control.Concurrent
import Control.Monad
import Data.IORef

reserve :: IORef Int -> IO Bool
reserve ref = atomicModifyIORef' ref $ \n -> if n > 0 then (n - 1, True) else (n, False)

main :: IO ()
main = do
  stock <- newIORef (10 :: Int)
  done <- newEmptyMVar
  replicateM_ 4 . forkIO $ do
    replicateM_ 1000000 $ do
      ok <- reserve stock
      when ok (modifyIORef' stock (+ 1))
    putMVar done ()
  replicateM_ 4 (takeMVar done)
  readIORef stock >>= print

在庫 stock から1つ取り置き、取り置けたらすぐに返す処理を、4つのスレッドがそれぞれ100万回繰り返すプログラムです。取り置いた数と返した数は同じなので、全部のスレッドが終われば在庫は最初の 10 に戻り、10 を表示するはずです。いまは GHC でコンパイルして実行するたびに値が変わり、9 や 7、6 と減るほか、12 のように最初の在庫より多くなることもあります。

Answer

Wrong

ok <- reserve stock
when ok (modifyIORef' stock (+ 1))

在庫が 10 より多くなるのが手がかりです。reserve は在庫が 1 以上のときしか引かないので、取り置きが成功した回数は返した回数と等しく、どの更新も正しく反映されていれば最後は 10 に戻ります。10 を超えるのは、どこかで取り置きの「1 を引く」更新が消えたときだけです。reserve の atomicModifyIORef' は、読んでから書くまでの間にほかのスレッドの更新を挟ませないので、消したのは返す側の modifyIORef' です。modifyIORef' は1回の呼び出しに見えますが、中身は readIORef で読んで、1 を足した値を writeIORef で書く2段の操作で、その間にスレッドが切り替わることがあります。

たとえば返す側のスレッドが在庫 9 を読んだところで切り替わり、別のスレッドが取り置いて 8 にしたとします。戻ってきた返す側は、読んだ 9 に 1 を足した 10 を書くので、8 にした取り置きは無かったことになります。その取り置きもあとで返されるので、在庫は1つ多くなります。間に入ったのが別の返却なら、その返却が消えて在庫は1つ少なくなります。どちらが何回起きるかはスレッドの切り替わり方で決まるので、結果は実行のたびに変わります。1

Right

ok <- reserve stock
when ok (atomicModifyIORef' stock (\n -> (n + 1, ())))

返す側も atomicModifyIORef' で 1 を足します。これで、同じ stock を書き換える箇所はどれも、読んでから書くまでの間にほかのスレッドの更新を挟ませなくなり、どの取り置きも返却も消えません。在庫の確認と引き算を reserve の中で不可分にしても、同じ IORef をほかの箇所が読んでから書いていれば、その間に入った不可分な更新は上書きで消えます。守りたい値を書き換える箇所は、1つ残らず不可分な更新にする必要があります。

  1. Data.IORef のドキュメントも、modifyIORef と modifyIORef' は不可分ではないので、複数のスレッドから使う IORef には atomicModifyIORef' を使うよう書いています。このプログラムは -threaded を付けずにコンパイルしても、GHC の実行時システムが一定時間ごとにスレッドを切り替えるので、1つの CPU の上でもこの割り込みが起きます。