2026-11-03
order_label.zig
const std = @import("std");
fn label(id: [3]u8) []const u8 {
const text = "id-" ++ id;
return text;
}
pub fn main(init: std.process.Init) !void {
var buf: [64]u8 = undefined;
var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
const stdout = &stdout_writer.interface;
const a = label("abc".*);
const b = label("xyz".*);
try stdout.print("{s} {s}\n", .{ a, b });
try stdout.flush();
}
3文字の ID の前に id- を付けたラベルを作る label で、ID abc と xyz のラベルを作って並べて表示するつもりのプログラムです。本来は id-abc id-xyz と表示するはずが、手元の Debug ビルドでは id-xyz id-xyz と表示されました。どう表示されるかは決まっておらず、ビルドの設定によって変わることがあります。
Answer
Wrong
fn label(id: [3]u8) []const u8 {
const text = "id-" ++ id;
return text;
}
++ が求めるのは、両辺の長さがコンパイル時に分かることだけで、値は実行時のものでもかまいません。id は実行時の引数ですが型が [3]u8 なので長さは 3 と決まっていて、"id-" ++ id はコンパイルが通ります。値が実行時に決まる以上、つないだ6文字の配列は label を呼ぶたびに、その呼び出しのローカルな領域(スタック)に作られます。text はその配列を指すポインタで、return text; はそれを []const u8 のスライスにして返します。
label から戻った時点で、その領域はもう label のものではありません。a は使い終わった領域を指したまま残り、2回目の label が同じ場所に id-xyz を作ると、a からもその文字列が見えます。寿命の切れた領域を読むのは、langref が illegal behavior と呼ぶ、結果の決まらない動作です。Debug ビルドの安全検査でも検出されず、ほかの値が表示されたり落ちたりすることもあります。1
Right
fn label(id: [3]u8) [6]u8 {
const text = "id-" ++ id;
return text.*;
}
戻り値の型を配列の [6]u8 にし、text.* で配列の中身を値として返します。配列は値なので、呼び出し側の a と b はそれぞれ自分の6バイトを持ち、label のローカルな領域が消えても中身は残ります。main はそのまま a と b を {s} で表示でき、id-abc id-xyz になります。
- 両辺がどちらもコンパイル時に分かる値なら、
++はコンパイル時に計算され、結果は文字列リテラルと同じくプログラムの静的な領域に置かれます。引数をcomptime id: [3]u8にすると、元のコードのままでもid-abc id-xyzと表示されます。ただしその場合、labelは実行時に決まる ID では呼べなくなります。