Namaran

Code daily. Without assist.

2026-08-26

sum_items.zig

const std = @import("std");
const fmt = std.fmt;
const items = [_][]const u8{ "3", "x", "4" };

pub fn main(init: std.process.Init) !void {
    var buf: [64]u8 = undefined;
    const file = std.Io.File.stdout();
    var writer = file.writer(init.io, &buf);
    const out = &writer.interface;
    var total: u32 = 0;
    for (items) |s| {
        const n = fmt.parseInt(u32, s, 10);
        total += n catch unreachable;
    }
    try out.print("{d}\n", .{total});
    try out.flush();
}

文字列の並びのうち10進数として読めるものだけを足し、読めないものは飛ばすつもりのコードです。"3"、"x"、"4" から 7 を出力するはずが、いまは何も出力せずに attempt to unwrap error: InvalidCharacter でパニックします。

Answer

Wrong

const n = fmt.parseInt(u32, s, 10);
total += n catch unreachable;

parseInt の結果 n は、u32 かエラーのどちらかを持つエラー共用体(error union)です。catch unreachable は、ここでエラーは起きないとコンパイラに約束する書き方で、エラーを処理するものではありません。"x" は数として読めないので n は error.InvalidCharacter になり、約束が破れて unreachable に届きます。これは Zig が illegal behavior と呼ぶ誤りで、Debug ビルドでは安全検査がここでパニックさせます1。合計を出力する前に止まるので、何も出力されません。

Right

const n = fmt.parseInt(u32, s, 10);
total += n catch continue;

catch continue は、n がエラーなら += を行わずに次の要素へ進みます。"x" は合計に入らず、3 と 4 だけが足されて 7 が出力されます。読めない項目がありうる入力に catch unreachable を使ってはいけません。使えるのは、文字列リテラルの "42" を読む場合のように、エラーが起きないことをプログラムの側で保証できるときだけです。

  1. 安全検査を外す ReleaseFast や ReleaseSmall のビルドでは、unreachable に届いたときの動作は決まっていません。パニックせずに誤った合計を出力することもありえます。