Namaran

Code daily. Without assist.

2026-08-26

unwind.zig

const std = @import("std");

fn step(w: *std.Io.Writer, n: u8) !u8 {
    defer w.print("d{d} ", .{n}) catch {};
    errdefer w.print("e{d} ", .{n}) catch {};
    if (n == 0) return error.Zero;
    return try step(w, n - 1) + 1;
}

pub fn main(init: std.process.Init) !void {
    var buf: [64]u8 = undefined;
    const file = std.Io.File.stdout();
    var writer = file.writer(init.io, &buf);
    const out = &writer.interface;
    const r = step(out, 2) catch 9;
    try out.print("{d}\n", .{r});
    try out.flush();
}

これは何を出力するでしょうか?

Answer

Output

e0 d0 e1 d1 e2 d2 9

step(out, 2) は step(w, 1) を、それが step(w, 0) を呼び、どの段も最初に defer と errdefer を1つずつ登録します。step(w, 0) は return error.Zero; でエラーを返して抜けます。defer は関数を抜けるときに必ず、errdefer はエラーを返して抜けるときだけ動き、どちらも登録したのと逆の順に動きます。あとから登録した errdefer が先なので、最初に e0 d0 が書かれます。

step(w, 1) では、try が受け取った値がエラーだったので、try はそのエラーを step(w, 1) の戻り値として返します。step(w, 1) も自分でエラーを返して抜けたことになり、その段の errdefer が動いて e1 d1 が続きます。step(w, 2) も同じで e2 d2 です。+ 1 はどの段でも計算されません。

main に戻った値は、エラーか u8 のどちらかを持つエラー共用体(error union)で、中身は error.Zero です。catch 9 はエラーのときに値を9に置き換えるので、r は9です。r を書くのは step(out, 2) が終わってからなので、9 は行の最後に来ます。

errdefer はエラーを作った step(w, 0) だけで動くと読むと e0 d0 d1 d2 9 に、書いた順に defer が先に動くと読むと d0 e0 d1 e1 d2 e2 9 になります。