Namaran

Code daily. Without assist.

2026-11-03

splat_rows.zig

const std = @import("std");

pub fn main(init: std.process.Init) !void {
    var buf: [64]u8 = undefined;
    var stdout_writer = std.Io.File.stdout().writer(init.io, &buf);
    const stdout = &stdout_writer.interface;
    var row: [3]u8 = @splat('.');
    var grid: [2][3]u8 = @splat(row);
    const views: [2][]const u8 = @splat(&row);
    row[0] = 'x';
    grid[1][1] = '#';
    for (grid, views) |g, v| {
        try stdout.print("{s} {s}\n", .{ g, v });
    }
    try stdout.flush();
}

これは何を出力するでしょうか?

Answer

... x.. と .#. x.. の2行です。

@splat は、結果の型が決める個数だけ引数の値を並べた配列を作ります。grid の型は [2][3]u8 なので、@splat(row) は [3]u8 の配列 row を2つ並べます。Zig の配列は値なので、並ぶのは row の中身を写した2つの別々の配列です。そのあと row[0] = 'x' と書き換えても grid の行は変わらず、grid[1][1] = '#' も2行目の配列だけを書き換えます。grid の2行は ... と .#. です。

views の要素の型は []const u8 のスライスで、@splat(&row) が2つ並べるのは row を指すポインタと長さの組です。スライスを複製しても、指す先の配列は複製されません。2つのスライスはどちらも同じ row を指すので、row[0] = 'x' は両方から見え、どちらの行も x.. になります。

grid の宣言だけを見て、どの行も同じ1つの row を共有していると読むと、.#. が2行続くか、x が grid にも現れると答えることになります。どちらになるかは、並べる要素が配列の値か、配列を指すスライスかで分かれます。1

  1. 以前の Zig には、配列を繰り返して並べる ** 演算子があり、[_]u8{'.'} ** 3 のように書けました。0.17 の言語リファレンスの演算子の表に ** は無く、同じ要素を並べるには @splat を使います。